Introduction à Mathematica

UPMC, Paris.

Julien Toulouse (julien.toulouse@upmc.fr)

Introduction

Qu'est-ce-que Mathematica ?

Mathematica est un logiciel de calcul formel et numérique développé par Wolfram Research. Il permet essentiellement de faire du calcul formel (manipulation d'expressions mathématiques sous forme symbolique, par exemple : calcul de dérivées, de primitives, simplication d'expressions, etc...) et du calcul numérique (évaluation d'expressions mathématiques sous forme numérique; par exemple : calcul des premières décimales du nombre π, évaluation approchée d'intégrales, etc...). Mathematica incorpore un langage de programmation sophistiqué et permet aussi de faire des graphiques. C'est un logiciel très utilisé en enseignement, dans la recherche scientifique et dans l'industrie.

Ou trouver Mathematica ?

L'UPMC a une licence globale permettant d'installer Mathematica sur tous les ordinateurs d'enseignement. En particulier, il est disponible sur les ordinateurs du L'UTES (Bâtiment Atrium), y compris ceux en libre service. La licence globale permet également aux enseignants et aux étudiants d'installer Mathematica sur n'importe quel ordinateur personnel (à la maison). Pour cela, connectez vous sur le site https://mon.upmc.fr, allez dans la rubrique "Mes Outils", puis suivez les instructions pour télécharger et installer Mathematica. L'activation se fait par un mot de passe et nécessite l'utilisation d’une adresse email en ...@upmc.fr.

Quelques autres outils et logiciels

Wolfram Alpha (www.wolframalpha.com) est un outil en ligne gratuit répondant à toutes sortes de questions (qui doivent être posées en anglais) et qui utilise une grande base de donnée et des calculs Mathematica.  Il permet d'accéder avec un simple navigateur internet à beaucoup de fontionnalités de Mathematica. Par exemple, la demande "derivative of sin(x)" (dérivée de sin(x)) calcule la réponse "cos(x)" et donne au passage d'autres informations utiles (propriétés de la fonction, courbes, développements limités, etc...). A essayer !

Un autre logiciel de calcul formel et numérique très utilisé est Maple. Il a des capacités similaires à celles de Mathematica. Il est également installé sur les ordinateurs du L'UTES.

Maxima est un logiciel libre et gratuit constituant une alternative aux logiciels commerciaux  que sont Mathematica ou Maple, avec néanmoins une interface graphique moins conviviale.

Matlab est un logiciel commercial de calcul numérique très utilisé, mais ne permet pas de faire du calcul formel. Scilab est un logiciel libre alternatif à Matlab.

Débuter en Mathematica

Noyau et interface graphique

Mathematica est composé de deux parties : le noyau ("kernel") et l'interface graphique ("front end"). Le noyau constitue le coeur du logiciel; il interprète les instructions d'entrée (écrites en langage Mathematica), puis calcule et retourne le résultat. L'interface graphique s'occupe de l'interaction avec l'utilisateur. Elle gère le fichier de travail (souvent appellé "feuille Mathematica" ou "notebook"), permet de taper les instructions et de visualiser les résultats. Le logiciel dispose aussi d'un traitement de texte, permettant ainsi d'inclure du texte parmi les calculs effectués; ce document a d'ailleurs été rédigé avec Mathematica. Plusieurs palettes d'outils sont disponibles pour aider à l'édition aussi bien de textes que d'expressions mathématiques (voir menu "Palettes").

Un fichier Mathematica

Un fichier Mathematica, aussi appelé "notebook", a une extension ".nb". Il est structuré en cellules ("cells"). Une cellule est constitué d'une ou de plusieurs lignes et est repérée par un crochet à droite du fichier. On peut avoir des cellules contenant des instructions Mathematica (cellule de type "In"), des résultats de calculs (cellule de type "Out"), du texte (cellule du type "Text"), un titre de paragraphe (cellule de type "Section"), etc ...

On peut sélectionner la totalité d'une cellule en cliquant sur son crochet à droite. On peut ensuite effacer (⇐), copier (Ctrl+c), couper (Ctrl+x), coller (Ctrl+v) la cellule, comme dans un logiciel de traitement de texte normal. Par défaut, les nouvelles cellules créées sont des cellules d'instructions Mathematica. On peut changer le type d'une cellule, après l'avoir selectionée, par le menu "Format > Style".

Une cellule peut contenir plusieurs sous-cellules, formant ainsi des groupes structurés de cellules. Pour faciliter la lecture du fichier, on peut ouvrir ou fermer des groupes de cellules en double-cliquant sur le crochet correspondant (ou en cliquant sur le triangle à gauche du titre).

Pensez à sauvergarder souvent votre fichier Mathematica (menu "File", puis "Save" ou "Save As"), les mauvaises manipulations étant fréquentes...

Menu Aide

Mathematica  inclut une documentation  exhaustive (voir le menu "Help", puis "Documentation Center" ou "Virtual Book"), incluant de nombreux exemples directement exécutables dans les pages d'aide.

La commande "Find Selected Function"  (ou touche "F1") est très pratique : dans un fichier Mathematica, après avoir placé le curseur sur une instruction Mathematica, appuyez sur F1 pour afficher la page d'aide correspondante à cette instruction.

Mon premier calcul en Mathematica

On tape une instruction (par exemple "1+2"), puis on l'exécute en maintenant enfoncé la touche "Maj" ou "Shift" (⇑) et en appuyant sur la touche "Entrée" (↵), le résultat ("3") s'affichant sur une nouvelle ligne :

1+2

Après exécution, la ligne d'instruction est désignée par "In" suivi du numéro de l'instruction depuis le démarrage du noyau. La ligne de résultat est désignée par "Out" suivi du numéro de l'instruction correspondante.

Le noyau ("kernel") de Mathematica est démarré lors du premier calcul. Si un calcul prend trop de temps et que l'on décide d'y renoncer en cours d'évaluation, on peut utiliser le menu "Evaluation", puis "Abort Evaluation". Parfois, il peut être également utile de quitter puis rédemarrer le noyau, afin d'effacer de la mémoire tous les résultats des calculs précédents.  Pour cela, on utilise le menu "Evaluation" puis "Quit Kernel". Le noyau sera alors redémarré lors du prochain calcul.

Calculs arithmétiques simples

Comme avec une calculatrice, on peut bien sûr faire de simples calculs arithmétiques avec Mathematica. Nous avons déjà vu l'exemple d'une addition. Voici un exemple d'un calcul avec une soustraction (-), une multiplication (*) et une division (/) sur des nombres décimaux :

(10.2-3.1)*6.2/2.9

Voici l'exemple d'un calcul avec une puissance :

2^4

Par défaut, Mathematica simplifie les fractions mais ne donne pas de valeur décimale :

4/6

Pour avoir une valeur décimale approché d'une expression, on peut utiliser la fonction "N" en donnant l'argument entre crochets :

N[4/6]

On peut aussi faire des calculs avec des nombres complexes, le nombre imaginaire i étant écrit "I" :

(2+3I)*(4-5I)

Définir des variables

Il est souvent pratique de définir des variables mathématiques contenant une valeur numérique. Par exemple, pour définir une variable nommée "x" et lui donner la valeur "5", on tape

x=5

Le signe "=" réalise ce que l'on appelle en informatique une "affectation" (et on dit qu'on affecte à "x" la valeur 5). Dans tous les calculs suivants, Mathematica replacera la variable "x" par sa valeur :

x^2

La ligne suivante change la valeur de "x" :

x=6+8

Le nom d'une variable peut être composé de plusieurs lettres et chiffres, par exemple

abc5=78

mais le nom d'une variable ne peut pas commencer par un chiffre.

On peut taper des équations avec les variables que l'on a définies de la même manière qu'en mathématiques, par exemple :

(2x+abc5)/4

le signe de la multiplication (*) entre "2" et "x" n'est pas nécessaire.

Pour effacer la valeur numérique d'une variable, on utilise la fonction "Clear" :

Clear[x]

On peut vérifier que la variable n'a alors plus de valeur numérique :

x

Quelques constantes mathématiques

Mathematica dispose de quelques variables déjà définies (constantes) et prêtes à être utilisées, par exemple :

- le nombre π

Pi

- le nombre e

E

- le nombre imaginaire i

I

- l'infini ∞ :

Infinity

Rappellons que pour forcer l'affichage d'une valeur décimale approchée, on peut utiliser la fonction "N". Voici les 100 premiers chiffres de π :

N[Pi,100]

Définir des fonctions

On peut définir ses propres fonctions en Mathematica. Par exemple, pour définir la fonction f(x) = (x^2) , on tape :

f[x_]=x^2

Dans le membre de gauche, l'argument "x" de la fonction est donné entre crochets et doit obligatoirement être suivi d'un tiret bas "_" (ou "underscore"), ce qui informe Mathematica que "x" est une variable muette qui devra être remplacée par l'argument avec lequel la fonction sera appelée. Attention : quand on définit une fonction comme ceci, il faut s’assurer que la variable “x” ne contienne pas déjà de valeur.

On peut alors appeler la fonction f avec comme argument "3" par exemple

f[3]

ou n'importe quelle expression, par exemple "2+4 z"

f[2+4z]

La fonction f peut être utilisée dans une expression quelconque

3+2y+5f[y]

On peut définir des fonctions à plusieurs variables

g[x_,y_]=x+y/x^2

Comme pour les variables, on peut effacer les fonctions qui viennent d'être définies par la fonction "Clear" :

Clear[f]

Clear[g]

Remarque : dans la définition d'une fonction, au lieu d’utiliser le signe “=” (affectation simple), on utilise parfois le signe ": =" qui signifie une "affectation retardée" :

f[x_]:=x^2

Le membre de droite n'est alors pas évalué et affecté à f(x) lors de la définition de la fonction ci-dessus mais il sera évalué plus tard à chaque utilisation de la fonction après substitution de "x" par une valeur. Ceci a l’avantage de fonctionner correctement même si la variable “x” contient déjà une valeur. Néanmoins, cette écriture a aussi des incovénients : elle peut conduire à une erreur dans certains cas où il est important d’évaluer d’abord le membre de droite avant de remplacer “x” par une valeur.

Quelques fonctions mathématiques

Mathematica dispose de nombreuses fonctions déjà définies.Voici quelques fonctions mathématiques courantes :

- racine carrée : (Sqrt[x])

Sqrt[x]

- exponentielle : (e^x)

Exp[x]

- logarithme népérien : ln(x)

Log[x]

- logarithme en base b : (Subscript[log, b])(x)  (le plus souvent, b=10)

Log[b,x]

- fonctions trigonométriques :

Sin[x]

Cos[x]

Tan[x]

ArcSin[x]

ArcCos[x]

ArcTan[x]

- valeur absolue : |x|

Abs[x]

- factorielle : n !

n!

ou

Factorial[n]

A retenir : les fonctions Mathematica déjà définies commencent toujours par une majuscule. Placez le curseur sur une fonction et appuyez sur F1 pour afficher la page d'aide de cette fonction. Si on se demande si Mathematica dispose d'une fonction particulière, ou si on a oublié le nom d'une fonction, le plus simple est de faire une recherche dans l'aide (menu "Help > Documentation Center").

Exemples de calculs formels

Mathematica dispose de fonctions très puissantes permettant d'effectuer toutes sortes de calculs formels. Quelques exemples :

- simplification de ((sin(x))^2)+((cos(x))^2)

Simplify[Sin[x]^2+Cos[x]^2]

- développement de l'expression (2x+3)((x^2)-6)

Expand[(2x+3)(x^2-6)]

- factorisation  de l'expression (x^2)-2x-3

Factor[x^2-2x-3]

- calcul de la dérivée de (x^n) par rapport à x

D[x^n,x]

- calcul d'un primitive de cos(x)

Integrate[Cos[x],x]

- calcul de l'intégrale (∫_0^∞)(e^(-(x^2)))dx

Integrate[Exp[-x^2],{x,0,Infinity}]

- calcul de la limite de (x-1) ln(x-1) quand x-> 1

Limit[(x-1) Log[x-1],x->1]

- calcul du développement limité de cos(x) autour de x=0   à l'ordre 10

Series[Cos[x],{x,0,10}]

- Résolution de l'équation (x^2)-3 x +2 = 0 en l'inconnue x

Solve[x^2-3x+2==0,x]

On obtient deux solutions réelles. Notez que pour définir une équation, on utilise le signe "= =" pour ne pas confondre avec le signe d'affectation "=".

Ces fonctions disposent en général d'un grand nombre d'options permettant de faire face à des cas particuliers ou difficiles. Consultez les pages d'aide de ces fonctions.

Exemples de calculs numériques

Parfois, un calcul formel n'est pas faisable, et il faut alors faire un calcul numérique approché. Quelques exemples :

- calcul d'une valeur approchée de l'intégrale (∫_1^3)ln(arctan(x))dx

NIntegrate[Log[ArcTan[x]],{x,1,3}]

- calcul approché des solutions de l'équation (x^5)+3(x^4)+2(x^3)-(x^2)+x+1=0

NSolve[x^5+3x^4+2x^3-x^2+x+1==0,x]

Faire des graphiques

Mathematica permet de faire toutes sortes de graphiques. Exemples :

- Tracé de la courbe de (((x-3))^2) pour x variant de -10 à 20 :

Plot[(x-3)^2,{x,-10,20}]

- Tracé superposé des courbes de sin(x), sin(2x),  et sin(3x) pour x variant de 0 à 2π :

Plot[{Sin[x],Sin[2x],Sin[3x]},{x,0,2Pi}]

Consultez la page d'aide de la fonction "Plot" pour voir toutes les options disponibles (on peut changer l'échelle, les couleurs, afficher le nom des axes, etc...).

- Tracé en 3D d'une fonction à deux variables  :

Plot3D[Sin[x ^2+y^2],{x,-3,3},{y,-1,1}]

Utilisation plus avancée de Mathematica

Palettes et raccourcis clavier

Les diverses palettes (voir menu "Palettes", puis par exemple "Classroom Assistant") permettent de trouver facilement les commandes Mathematica les plus courantes et de taper des formules mathématiques avec le format d'écriture naturel. Par exemple, elles permettent de taper l'expression suivante

(x^2+3)Exp[-y]/(z+Pi)

sous une forme plus lisible

((((x^2)+3)(E^(-y)))/(z+π))

Pour taper plus vite, il est également utile de connaitre quelques raccourcis clavier :

- Ctrl+6 : pour faire les puissances (exemple : (x^2))

- Ctrl+/ : pour faire les fractions (exemple : (1/2))

- EsceeEsc : pour écrire l'exponentielle e (équivalent à Exp)

- EscpEsc : pour écrire le nombre π (équivalent à Pi)

- EsciiEsc : pour écrire le nombre imaginaire i (équivalent à I)

- EscinfEsc : pour écrire ∞ (équivalent à Infinity)

- Esc->Esc : pour écrire -> (équivalent à ->)

etc...

Listes

Dans Mathematica, on utilise souvent les listes qui sont des ensembles d'éléments regroupés entre accolades et séparés par des virgules. Par exemple,

{a,b,c}

est une liste. Les éléments a, b,... d'une liste peuvent être n'importe quoi (nombre, variables, fonctions, ...) y compris une liste eux-mêmes !  On peut donc imaginer des listes imbriquées complètement générales du genre :

{{a,3},b,{coucou,h[x],-56}}

Nous verrons plus loin qu'une liste simple du type {a,b,c} représente un vecteur de dimension 3 et qu'une liste de listes du type {{a,b},{c,d},{e,f}} représente une matrice de dimension 3×2.

On peut bien sûr affecter une liste à une variable :

maliste={a,b,-5}

On peut accéder individuellement au ième élément d'une liste avec la syntaxe suivante [[i]], par exemple :

maliste[[2]]

maliste[[3]]

Un détail : on peut utiliser les raccourcis clavier Esc[[Esc et Esc]]Esc  pour rendre les doubles crochets plus jolis et plus lisibles :

maliste[[2]]

Il existe dans Mathematica beaucoup de fonctions de manipulation des listes (pour ajouter des éléments, en extraire, etc...). Consultez l'aide si besoin.

Substitution

L'opération "/." (correspondant à une fonction appelée "ReplaceAll" en Mathematica) permet de substituer dans une expression une variable par une valeur ou par une autre variable. Par exemple, pour remplacer z par 2 dans l'expression (((z+1))^2), on peut écrire

(z+1)^2/.z->2

"z -> 2" s'appelle une règle ("rule" en anglais) de substitution. L'avantage est que "2" n'est pas affecté à la variable z globalement dans tout le notebook, mais la substitution ne se fait que localement dans l'expression ci-dessus, et on peut continuer à utiliser z par la suite comme une variable non définie :

z

On peut faire plusieurs substitutions avec la syntaxe suivante

(z+1+abc)^2/.{z->2,abc->m}

Souvent les fonctions Mathematica retournent les résultats sous forme d'une liste de règles, par exemple

resultat=Solve[x^2-x-2==0,x]

où nous avons stocké le résultat dans la variable "resultat". La première solution x=-1 correspond au premier élément de la liste "resultat" :

resultat[[1]]

Puisque "resultat[[1]]" est sous la forme d'une règle, il suffit d'appliquer une substitution sur la variable "x" pour extraire la valeur "-1" :

x/.resultat[[1]]

Pipeline

L'opération "//" (appelée "pipeline", ou tube en français) permet d'appliquer une fonction au dernier résultat avec un syntaxe inversée. Ainsi, l'instruction suivante

x//f

est équivalente à

f[x]

L'exemple ci-dessus ne présente pas vraiment d'intérêt et rend l'écriture beaucoup moins claire. En revanche, le pipeline est très pratique pour appliquer une fonction Mathematica à une expression déjà tapée sans avoir à revenir au début de la ligne, par exemple :

(Cos[x]+Sin[x])^2-2Cos[x] Sin[x]//Expand

On peut empiler plusieurs fonctions avec les pipelines, par exemple appliquons la fonction "Simplify" au résultat précédent

(Cos[x]+Sin[x])^2-2Cos[x] Sin[x]//Expand//Simplify

Autre exemple, appliquons la fonction "N" au nombre π avec un pipeline

π//N

Il est également possible d'utiliser le pipeline pour appliquer une fonction avec plus d'un seul argument, on utilise alors la syntaxe suivante

π//N[#,100]&

qui est équivalent à

N[π,100]

Le symbole "#" repère l'endroit où l'expression qui précéde (ici π) sera insérée et "&" marque la fin de la fonction. La simplificité de la syntaxe est néanmoins un peu perdue.

Minimisation/maximisation

On cherche souvent le minimum ou le maximum global d'une fonction f(x) par rapport à x. Les fonctions "Minimize" et "Maximize" permet d'effectuer cette tâche :

f[x_]:=5+(x-3)^2

Minimize[f[x],x]

g[x_]:=Exp[-Abs[x+2]]

Maximize[g[x],x]

Ces fonctions retourne la valeur de l'extrémum et sa localisation en x.

Il existe également des variantes numériques de ces fonctions dans le cas où l'extrémum n'est pas calculable exactement :

NMinimize[x^4+x^3+x^2+x+1,x]

NMaximize[-x^4+x^3+x^2+x+1,x]

Les fonctions "FindMinimum" et "FindMaximum" permettent de rechercher des minimums et maximums locaux  en donnant un point de départ. Par exemple, la recherche d'un minimum local de la fonction sin(x) exp(-(x^2)) en partant de x=-1.5 donne

FindMinimum[Sin[x] Exp[-x^2],{x,-1.5}]

En partant de x=1.2, on trouve un autre minimum local

FindMinimum[Sin[x] Exp[-x^2],{x,1.2}]

De la même manière, voici un exemple de recherche d'un maximum local en partant de x = 2

FindMaximum[Sin[x] Exp[-x^2],{x,2}]

Systèmes d'équations

La fonction "Solve" que l'on a déjà vue ne permet pas uniquement de résoudre une seule équation à une seule inconnue. Elle peut traiter n'importe quel nombre d'équations et d'inconnues. Par exemple, pour résoudre le système d'équations linéaires à 3 inconnues suivant

{({{x+2y-z=2}, {({{4x+2y-3z=1}, {2x-y+z=-5}})}})

on utilise "Solve" de la façon suivante (après éventuellement avoir effacé avec la fonction "Clear" toutes valeurs pouvant être déjà contenues dans x, y et z)

Clear[x,y,z]

Solve[{x+2y-z==2,4x+2y-3z==1,2x-y+z==-5},{x,y,z}]

On peut aussi essayer de résoudre des équations non linéaires (qui peuvent avoir de multiples solutions)

Solve[{x^2+2/y==2,4x+2y==1},{x,y}]

mais très vite les calculs exacts ne sont plus faisables même par Mathematica et il faut alors utiliser une résolution numérique approchée avec "NSolve"

NSolve[{x^2+y^5==2,4x^3+2/y==1},{x,y}]

Calcul vectoriel

En Mathematica, les composantes d'un vecteur s'écrivent avec une liste simple, c'est-à-dire qu'elles sont regroupées entre accolades et séparées par des virgules. Par exemple, dans un espace de dimension 3, définissons le vecteur u suivant :

u={2,-3,1}

Chaque composante d'un vecteur est individuellement accessible (et modifiable) avec la syntaxe u[[i]] où i est le numéro de la composante. Ainsi, la 2ème composante s'obtient par

u[[2]]

ou en utilisant les raccourcis clavier Esc[[Esc et Esc]]Esc  pour rendre les doubles crochets plus jolis et plus lisibles :

u[[2]]

On peut faire un certain nombre d'opérations sur ce vecteur. Par exemple, une multiplication par un scalaire :

3 u

ou le calcul de sa norme  :

Norm[u]

Définissons maintenant un deuxième vecteur v

v={4,-1,5}

En Mathematica, la multiplication directe u * v (ou simplement u  v) signifie multiplier la ième composante de u avec la même ième composante de v

u* v

Le produit scalaire est obtenu par l'opération "."

u.v

Si nous chargons le paquetage "VectorAnalysis" (qui n'est pas chargé par défaut)

Needs["VectorAnalysis`"]

nous avons alors accès à d'autres fonctions d'analyse vectorielle, comme la fonction "CrossProduct" qui calcule le produit vectoriel de deux vecteurs

CrossProduct[u,v]

Traitement de données numériques

Imaginons que nous disposions de données numériques sous la forme d'une série de points (x,y). Le format adéquat pour représenter ces données dans Mathematica est une liste de listes :

donnees={{0.,1.23},{1.,3.5},{2.,6.4},{3,8.3}};

On peut alors facilement tracer un graphique avec ces données

ListPlot[donnees,PlotMarkers->{Automatic,Medium}]

On a souvent besoin de faire un fit (aussi appelé ajustement ou régression) de ces données. Par exemple, les paramètres a et b d'un fit linéaire y= a x + b peuvent être déterminés avec la fonction" FindFit" :

Clear[a,b,x]

parametres=FindFit[donnees,a x+b,{a,b},x]

Vérifions la qualité du fit en superposant (avec la fonction "Show") le graphique des données et celui du fit :

Show[ListPlot[donnees,PlotMarkers->{Automatic,Medium}],Plot[a x+b/.parametres,{x,0,5}]]

Parfois, au lieu d'un fit, on préfère utiliser une interpolation des données. La fonction "Interpolation" réalise cette tâche :

f=Interpolation[donnees]

Elle retourne une fonction f donnant une interpolation des données pour n'importe quelle valeur de x dans le domaine de définition indiqué [0,3]. Par défault, Mathematica réalise une interpolation de degré 3. Par exemple, la valeur de la fonction d'interpolation f(x) pour x=1.5  est

f[1.5]

On peut aussi tracer l'interpolation, superposée aux données :

Show[ListPlot[donnees,PlotMarkers->{Automatic,Medium}],Plot[f[x],{x,0,5}]]

Equations différentielles

La fonction "DSolve" permet de résoudre des équations différentielles. Prenons l'exemple d'une équation différentielle linéaire du 1er ordre : y'(x)+2 y(x)=sin(x)

Clear[x,y]

DSolve[y'[x]+2y[x]== Sin[x],y[x],x]

C[1] est une constante d'intégration. On peut ajouter une condition initiale (ou aux limites) y(0)=0 pour déterminer la constante C[1] :

DSolve[{y'[x]+2y[x]== Sin[x],y[0]==0},y[x],x]

Voici l'exemple d'une équation différentielle linéaire du 2ème ordre

DSolve[y''[x]+3y'[x]+2y[x]== Exp[x],y[x],x]

et d'une équation différentielle non linéaire

DSolve[((x^2)-((y[x])^2))y'[x]-2x y[x]== 0,y[x],x]

Si l'équation différentielle n'est pas soluble exactement, on peut trouver une solution numérique avec la fonction "NDSolve" (voir l'aide).

Boucle Do

Une boucle "Do" permet d'exécuter plusieurs fois une instruction.  La commande "Do[instruction, {i, debut, fin}]" fait varier l'entier "i" (appelé "itérateur") de l'entier "debut" à l'entier "fin" et exécute à chaque fois "instruction". Par exemple, pour afficher "Coucou" 5 fois, on utilise une boucle Do exécutant l'instruction Print["Coucou"] lorsque i varie de 1 jusqu'à 5 :

Do[Print["Coucou"],{i,1,5}]

ce qui ne semble pas servir à grand chose... Les boucles Do sont plus intéressantes si on a besoin d'utiliser l'entier i dans l'instruction. Par exemple, affichons les 10 premiers entiers

Do[Print[i],{i,1,10}]

Plus intéressant encore, utilisons une boucle Do pour calculer la somme des 100 premiers entiers s=(∑_(i=1)^100)i. On commence par initialiser la variable s à 0

s=0

puis on fait varier i de 1 jusqu'à 100 et à chaque itération on calcule s+i et on affecte le résultat à la variable s

Do[s=s+i,{i,1,100}]

A la fin des itérations, la variable  s contient la somme recherchée

s

Il est souvent plus clair (et plus sûr) de regrouper ces trois instructions en une seule instruction dans une seule cellule en les séparant par des ";" (qui permettent de supprimer les affichages intermédiaires)

s=0;
Do[s=s+i,{i,1,100}];
s

Il se trouve que Mathematica dispose d'une fonction "Sum" permettant de faire cette somme plus directement

Sum[i,{i,1,100}]

Néanmoins, les boucles Do permettent de faire beaucoup plus de choses.

Par défaut, l'itérateur varie par incrément de 1, mais on peut aussi utiliser n'importe quel autre incrément. Par exemple, dans la boucle Do suivante l'entier j varie de 3 jusqu'à 10 par incrément de 2

Do[Print[j],{j,3,10,2}]

Et dans la boucle suivante l'entier j varie de 5 jusqu'à 2 par incrément de -1

Do[Print[j],{j,5,2,-1}]

Enfin, on peut exécuter plusieurs intructions dans une boucle Do en les séparant par ";". Par exemple, calculons la somme s et le produit p des 10 premiers entiers, s=(∑_(i=1)^10)i et p=(∏_(i=1)^10)i, avec une seule boucle Do :

s=0;
p=1;
Do[
s=s+i;
p=p*i,{i,1,10}];
Print[s];
Print[p];

Les retours à la ligne ne sont pas obligatoires mais facilitent la lecture.

Exercice : vérifier que le produit scalaire des deux vecteurs précédement définis peut être calculé explicitement en faisant les produits composante par composante avec la boucle Do suivante :

u={2,-3,1};
v={4,-1,5};
produit=0;
Do[produit=produit+u[[i]] v[[i]],{i,1,3}];
produit

Structure conditionnelle If

La structure conditionnelle "If" permet de choisir d'exécuter une instruction ou une autre suivant qu'une condition (appelée expression logique en informatique) est vraie ou fausse. La syntaxe est la suivante : "If [expression logique, instruction1, instruction2]". Si "expression logique" est vraie ("True" en Mathematica) alors uniquement "instruction1" sera exécutée; si au contraire "expression logique" est fause ("False" en Mathematica) alors uniquement  "instruction2" sera exécutée.

Par exemple, utilisons une structure "If" pour écrire la fonction f(x) définie par morceaux : f(x)=(e^x) si x>0 et f(x)=(x^2) si x≤0

f[x_]:=If[x>0,Exp[x],x^2]

Etant donné deux variables x et y (les ";" permettent de supprimer l'affichage du résultat qui est sans intérêt ici)

x=-2;

y=3;

voici quelques exemples d'expressions logiques pouvant être utilisées dans un "If" :

- test d'égalité (attention, il faut utiliser "==" et non pas "=")

x==y

- test de non égalité

x!=y

- test de supériorité

x>y

- test de supériorité ou d'égalité

x>=y

- test d'infériorité

x<y

- test d'infériorité ou d'égalité

x<=y

On peut aussi combiner des expressions logiques avec un ET logique ("&&" en Mathematica) ou "OU" logique ("| |" en Mathematica). Par exemple, pour tester si   x<0  ET y=0, on écrit

x<0&&y==0

pour tester si   x<0  OU y=0, on écrit

x<0||y==0

Calcul matriciel

En Mathematica, une matrice est définie comme une liste de vecteurs lignes. Par exemple, définissons la matrice A suivante de dimension 3×3

A={{1,1,0},{2,-2,0},{0,0,3}}

On peut utiliser la fonction "MatrixForm" (par exemple en pipeline) pour afficher la matrice sous forme plus claire

A//MatrixForm

La syntaxe A[[i,j]] (ou A[[i]][[j]] ) permet d'accéder à l'élement (i,j) de A, par exemple

A[[2,1]]

Essayons quelques opérations sur cette matrice :

- multiplication par un scalaire

3A

- calcul de la transposée

Transpose[A]//MatrixForm

- calcul de la trace

Tr[A]

- calcul du déterminant

Det[A]

- calcul de la matrice inverse

Inverse[A]

- calcul du cube de la matrice, (A^3)

MatrixPower[A,3]

- calcul des valeurs propres et des vecteurs propres

Eigenvalues[A]

Eigenvectors[A]

Définissons maintenant une deuxième matrice rectangulaire B

B={{-3,2},{1,0},{7,8}}

B//MatrixForm

Le produit matriciel de A par B se calcule avec l'opération "."

A.B

Par contre, les dimensions de ces matrices interdissent le produit matriciel de B par A  et Mathematica ne s'y trompe pas et refuse de le faire

B.A

Exercice : vérifier que le produit matriciel peut être calculé plus explicitement en faisant les produits élément par élément avec les boucles Do imbriquées suivantes :

produit={{0,0},{0,0},{0,0}};
Do[
Do[
Do[produit[[i,j]]=produit[[i,j]]+A[[i,k]] B[[k,j]],{k,1,3}],
{i,1,3}],
{j,1,2}];
produit

Programmation avec des modules

En Mathematica, un "Module" est l'équivalent de ce que l'on appelle souvent une "routine" dans d'autres langages de programmation. Il s'agit d'un ensemble d'instructions regroupés dans une même entité indépendante. Reprenons l'exemple du calcul du produit scalaire de deux vecteurs par une boucle Do. On peut utiliser un module pour définir une fonction "produitscalaire" prenant comme arguments deux vecteurs u et v, et retournant la valeur de leur produit scalaire :

produitscalaire[u_,v_]:=Module[{produit,i},
produit=0;
Do[produit=produit+u[[i]] v[[i]],{i,1,3}];
produit]

Dans cet exemple, "{produit, i}" sur la première ligne indique que "produit" et "i" sont des variables locales, c'est-à-dire qu'elles seront modifiées uniquement à l'intérieur du Module, et pas globalement pour tout le notebook. Utiliser des variables locales limite les risques d'erreur en évitant les possibles conflits avec d'autres parties du notebook où ces mêmes variables pourraient être aussi utilisées. L'autre avantage de créer des modules est de pouvoir réutiliser facilement autant que l'on veut une même partie de code. Par exemple, on peut calculer le produit scalaire des vecteurs  {2, -3, 1} et {4, -1, 5}

produitscalaire[{2,-3,1},{4,-1,5}]

puis le produit scalaire des vecteurs  {2, 0, 1} et {2, -1, 3}

produitscalaire[{2,0,1},{2,-1,3}]

Découper un long code en petits modules indépendants permet de diminuer la complexité du code. C'est une bonne pratique de programmation.