Exercices : Dérivation

Exercice 1

1) Définir dans Mathematica la fonction (Subscript[h, 1])(x)=(e^(-x)).

Définissons la fonction

h1[x_]=Exp[-x]

2) Calculer sa dérivée première, sa dérivée seconde, et sa dérivée troisième.

La commande “D” peut être utilisée pour calculer la dérivée :

D[h1[x],x]

ceci correspond à la limite du taux de variation :

Limit[((h1[x+ε]-h1[x])/ε),ε->0]

On peut aussi calculer la dérivée 2ème :

D[h1[x],{x,2}]

la dérivée 3ème :

D[h1[x],{x,3}]

etc...

3) Utiliser la commande “SeriesCoefficient” pour calculer la dérivée  (n^(ème)).

Pour trouver la derivée nème générale, on peut utiliser :

Simplify[n! SeriesCoefficient[h1[x],{x,x,n }],Assumptions->n≥0]

4) Même questions avec la fonction (Subscript[h, 2])(x)=1/(1-x).

Comme précédement :

h2[x_]=(1/(1-x))

D[h2[x],x]

D[h2[x],{x,2}]

D[h2[x],{x,3}]

Simplify[n! SeriesCoefficient[h2[x],{x,x,n }],Assumptions->n≥0]

Exercice 2

1) En utilisant la commande “If”, définir dans Mathematica la fonction définie par morceaux : f(x)=({{{, ({{1-(e^(-1/(x^2))), si   x≠0}, {1, si  x=0.}})}}).

Un fonction définie par morceaux peut être définie en Mathematica avec la commande “If” :

f[x_]=If[x≠0,1-Exp[-1/x^2],1]

2) Vérifier que la fonction est continue en x=0.

La fonction est bien continue en x=0 :

Limit[1-Exp[-1/x^2],x->0]

On peut vérifier avec le graphe :

Plot[f[x],{x,-1,1}]

3) Calculer la dérivée de la fonction. Est-elle définie en x=0 ?

La dérivée pour x≠0 est

D[1-Exp[-1/x^2],x]

Elle tend vers 0 en x=0 :

Limit[-((2 x Exp[-(1/(x^2))])/((((x^2)))^2)),x->0]

La dérivée peut donc être définie par :

f1[x_]=If[x≠0,-((2 x Exp[-(1/(x^2))])/((((x^2)))^2)),0]

4)  Même questions pour la fonction ϕ(x)=({{{, ({{(x^3)sin(1/x), si   x≠0}, {0, si  x=0.}})}})

Comme précédement :

ϕ[x_]=If[x≠0,x^3 Sin[1/x],0]

La fonction est bien continue en x=0 :

Limit[x^3 Sin[1/x],x->0]

La dérivée pour x≠0 est

D[x^3 Sin[1/x],x]

Elle tend vers 0 en x=0 :

Limit[-x Cos[(1/x)]+3 (x^2) Sin[(1/x)],x->0]

La dérivée peut donc être définie par :

ϕ1[x_]=If[x≠0,-x Cos[(1/x)]+3 (x^2) Sin[(1/x)],0]

Traçons la fonction et sa dérivée :

Plot[{ϕ[x],ϕ1[x]},{x,-0.3,0.3},PlotStyle->{Blue,Red}]

La dérivée s’annule en x=0 et oscille autour de x=0.

Exercice 3

1) Définir dans Mathematica la fonction (Subscript[ψ, 1])(x)=ln(tan(x/2)) et montrer qu’elle est périodique.

On définit la fonction

ψ1[x_]=Log[Tan[(x/2)]]

Essayons de la traçer :

Plot[ψ1[x],{x,-10,10}]

La fonction semble 2π-périodique. Vérifions :

ψ1[x+2π]==ψ1[x]//Simplify

2) Déterminer le domaine de définition de (Subscript[ψ, 1])(x).

Sur l’intervalle [0,2π], elle n’est définie que quand tan(x/2) > 0 :

Reduce[{Tan[(x/2)]>0,0<x<2π},x]

Il existe aussi directement une fonction pour trouver le domaine de définition :

FunctionDomain[ψ1[x],x]

Remarque : on peut aussi essayer également WolframAlpha

WolframAlpha["Log[Tan[(x/2)]]"]

3) Calculer la dérivée de (Subscript[ψ, 1])(x).

La dérivée est

ψ1d[x_]=D[ψ1[x],x]//Simplify

4) Tracer (Subscript[ψ, 1])(x) et sa dérivée sur le même graphe.

Plot[{ψ1[x],ψ1d[x]},{x,0,π}]

5) Même questions pour la fonction (Subscript[ψ, 2])(x)=ln(tan(x/2+π/4)).

On procéde de manière similaire pour la deuxième fonction :

ψ2[x_]=Log[Tan[(x/2)+(π/4)]]

Plot[ψ2[x],{x,-10,10}]

ψ2[x+2π]==ψ2[x]//Simplify

Reduce[{Tan[(x/2)+(π/4)]>0,0<x<2π},x]

ψ2d[x_]=D[ψ2[x],x]//Simplify

Plot[{ψ2[x],ψ2d[x]},{x,0,2π}]

Exercice 4

1) Utiliser Mathematica pour montrer que sin x≤ x pour x≥0.

On veut montrer que sin x≤ x pour x≥0. On peut commencer par tracer les deux fonctions pour vérifier visuellement

Plot[{Sin[x],x},{x,0,10},PlotStyle->{Blue,Red}]

On peut démontrer cette inégalité en remarquant que la dérivée de sin x - x est toujours négative

D[Sin[x]-x,x]

sin x -x est donc toujours décroissante et puisqu’elle vaut 0 en x=0  on a bien sin x -x ≤ 0.

On peut aussi vérifier pour quelles valeurs de x l’inégalité est vérifiée directement avec Mathematica :

Reduce[Sin[x]≤x,x]

2) De même, montrer que ln(1+x)≤x pour x>-1.

On procéde de manière similaire pour la deuxième fonction :

Plot[{Log[1+x],x},{x,0,10},PlotStyle->{Blue,Red}]

D[Log[1+x]-x,x]

Reduce[Log[1+x]≤x,x]

Exercice 5

1) Définir dans Mathematica la fonction de Weierstrass : f(x)=(∑_(n=0)^nmax)(a^n)cos((b^n)π x) .

On définit la fonction de Weierstrass :

f[x_,a_,b_,nmax_]=Sum[a^n Cos[b^n π x],{n,0,nmax}];

2) Tracer la fonction sur l’intervalle [-10,10] pour  a=7/10, b=10, et nmax=1, 10, 100.

On trace la fonction sur l’intervalle [-10,10] pour différentes valeurs de nmax :

Plot[f[x,7/10.,10.,1],{x,-10,10},PlotPoints->100]

Plot[f[x,7/10.,10.,10],{x,-10,10},PlotPoints->100]

Plot[f[x,7/10.,10.,100],{x,-10,10},PlotPoints->100]

On peut aussi utiliser la commande Manipulate pour faire varier nmax :

Manipulate[Plot[f[x,7/10.,10.,nmax],{x,-10,10},PlotPoints->100],{nmax,0,100}]

3) Vérifier graphiquement que la fonction tend vers une valeur finie quand nmax->∞ par exemple en x=1 :

Vérifions graphiquement pour x=1 que la fonction tend vers une valeur finie quand nmax->∞ :

Plot[f[1.,7/10.,10.,nmax],{nmax,0,100}]

4) Calculer la dérivée de f(x), et vérifier graphiquement sa limite quand nmax->∞  en x=1. Commenter.

Définition à présent la dérivée

f1[x_,a_,b_,nmax_]=D[f[x,a,b,nmax],x]

et vérifions sa limite quand nmax -> ∞ en x=1 :

Plot[f1[1.,7/10.,10.,nmax],{nmax,0,100}]

la dérivée oscille avec nmax : elle n’a pas de limite. La fonction n’est pas dérivable dans cette limite.

Remarque: Notez que la fonction a un comportement fractal : quand on zoom sur un intervalle de plus en plus petit, la courbe de la fonction continue à resembler à la même chose :

Plot[f[x,7/10.,10.,100],{x,-10,10},PlotPoints->100]

Plot[f[x,7/10.,10.,100],{x,-1,1},PlotPoints->100]

Plot[f[x,7/10.,10.,100],{x,-0.1,0.1},PlotPoints->100]

Plot[f[x,7/10.,10.,100],{x,-0.01,0.01},PlotPoints->100]